<- До підрозділу

Керування ПЧ Danfoss з використанням профілю FC

Довідкова частина

Профіль FC є основним профілем для керування ПЧ Danfoss через мережу. Аналогічно іншим профілям профіль FC передбачає два слова керування та два слова контролю:

Слова керування:

• CTW - Frequency converter control word register, слово команди
• REF - Bus reference register

Слова контролю:

• STW - Frequency converter status word register, слово стану
• MAV - Frequency converter main value register

Керування автоматів станів передбачає виставлення відповідних бітів в слові, без забезпечення послідовностей переходу.

Задане значення швидкості передається на перетворювач частоти у відносному значенні у %. Значення передається у вигляді 16-розрядного слова REF в діапазоні 0-16384 (0-4000 hex) що відповідає 0-100% від максимальної. Від’ємні значення форматуються з використанням доповнення 2. Фактична вихідна частота (MAV) масштабується так само, як REF.

рис.1. Діапазон частот в REF та MAV

Слово команди CTW

Таблиця 1. Біти слова команди

Слово статусу STW

Таблиця 2. Біти слова статусу

Практична частина

Постановка задачі

Для практичної частини використовується наступна конфігурація

Передбачається керування з ПЛК:

• запуск/зупинка двигуна;
• керування швидкістю в розімкнутому режимі;

Контроль роботи приводу:

• контроль режиму роботи приводу (функціонування, наявність помилки, місцевий/дистанційний);
• поточна швидкість;

Налаштування ПЧ для комунікації

У даному прикладі ми опустимо налаштування в ПЧ параметрів двигуна та інших налаштувань, що не стосуються теми. Зупинимося тільки на налаштуваннях мережі. Усі налаштування керування через послідовний порт наведені на рис.2.

Таблиця 3. Налаштування ПЧ

рис.2. Комунікаційні параметри ПЧ FC51 (не знайшов англійською)

Створення функціонального блока

Для керування ПЧ створимо функціональний блок DNFCTRL. Параметри вказані в таблиці 4.

Таблиця 4. Параметри ФБ DNFCTRL

Програма користувача наведена нижче.

#SPEEDCUR := INT_TO_REAL(#MAV) * 100/16384;
IF #START THEN
    #cmdStart := true;
    #cmdRamp := true;
ELSE
    #cmdStart := false;
    #cmdRamp := true;
END_IF;
    
#staControlReady := #STW.%X0; 		//00 Control NOT ready / Control ready
#staFreqConvReady := #STW.%X1; 		//01 frequency converter NOT ready / Frequency converter ready
#staEnable := #STW.%X2; 			//02 Coasting / Enable
#staTrip := #STW.%X3; 				//03 No error / Trip
#staError := #STW.%X4; 				//04 No error / Error (no trip)
#staTriplock := #STW.%X6; 			//06 No error /Triplock
#staWarning := #STW.%X7; 			//07 No warning /Warning
#staSpeedEqRef := #STW.%X8; 		//08 Speed≠reference /Speed=reference
#staBusCtrl := #STW.%X9; 			//09 "Local" operation /Bus control
#staFreqLimOk := #STW.%X10; 		//10 Out OF frequency limit /frequency limit OK
#staInoperation := #STW.%X11; 		//11 No operation /In operation
#staStopped := #STW.%X12; 			//12 Frequency converter OK / Stopped, auto start
#staVoltExceeded := #STW.%X13; 		//13 Voltage OK /Voltage exceeded
#staTorqueExceeded := #STW.%X14; 	//14 Torque OK /Torque exceeded
#staTimerExceeded := #STW.%X15; 	//15 Timer OK /Timer exceeded

#REF := REAL_TO_INT(#SPEEDSP * 16384 / 100.0);
#CTW.%X0 := false; 					//00 Reference value /External selection lsb
#CTW.%X1 := false; 					//01 Reference value /External selection msb
#CTW.%X2 := #cmdRamp; 				//02 DC brake /Ramp
#CTW.%X3 := NOT #cmdCoasting; 		//03 Coasting /No coasting
#CTW.%X4 := NOT #cmdQuickStop; 		//04 Quick stop /Ramp
#CTW.%X5 := #cmdRamp; 				//05 Hold output frequency / Use ramp
#CTW.%X6 := #cmdStart; 				//06 Ramp stop / Start
#CTW.%X7 := #cmdReset; 				//07 No function / Reset
#CTW.%X8 := false; 					//08 No function / Jog
#CTW.%X9 := #cmdRamp2; 				//09 Ramp 1 / Ramp 2
#CTW.%X10 := true; 					//10 Data invalid / Data valid
#CTW.%X11 := #cmdRelay1On; 			//11 Relay 01 open / Relay 01 active
#CTW.%X12 := #cmdRelay2On; 			//12 Relay 02 open / Relay 02 active
#CTW.%X13 := #cmdSellsb; 			//13 Parameter set-up / Selection lsb
#CTW.%X15 := #cmdReverse; 			//15 No function / Reverse

У програмі реалізований шаблон та найпростіше керування ПЧ командами запуску та зупинки за рампою в залежності від входу START. Усіми іншими бітами можна керувати через біти екземплярного DB.

Слова стану STW та плинного значення MAV приходять в ФБ через входи. Вони мають подаватися на вхід ФБ з фрагмента програми що забезпечує читання змінних з ПЧ. Аналогічно вихідні змінні CTW та REF , які змінюються всередині ФБ мають передаватися іншим фрагментом програми на ПЧ. Задане значення SPEEDSP в діапазоні 0-100% перетворюється у відповідне REF, а дійсне ціле значення з ПЧ MAV перетворюється у SPEEDCUR.

Реалізація основної програми

Реалізація в основній програмі передбачає виклик ФБ DNFCTRL з відповідним створеним екземплярним DB. Для реалізації обміну по мережі Modbus реалізований інший фрагмент програми, який описаний в практичному занятті Реалізація Modbus Master з використанням функції MB_MASTER для S7-1200.

#DNFFCCTRL_ROAST(STW:="IOMB".DNFROAST_RD.STW,
                 MAV:="IOMB".DNFROAST_RD.MAV,
                 START:="IO".MROAST_KV_OUT,
                 SPEEDSP:="IO".MROAST_SPD_OUT,
                 CTW =>"IOMB".DNFROAST_WR.CTW,
                 "REF" =>"IOMB".DNFROAST_WR."REF");

Практичне заняття розробив Олександр Пупена.

Якщо Ви хочете залишити коментар у Вас є наступні варіанти:

• Обговорення у WhatsApp
• Обговорення в Телеграм
• Група у Фейсбуці

Про проект і можливість допомогти проекту написано тут